/* DVD IR Synchronizer for Toshiba SD1091EKE
 * Developed for Art Installation  by Steina
 * Code written by Joe Foley <foley@ru.is>
 * on 2013-09-08
 *
 * Requires libraries:
 *  Arduino-IRremote https://github.com/shirriff/Arduino-IRremote
 *
 * More codes at http://www.lirc.org/
 * The compatible remote is SE-R0301
 * We use the codes for the SE-R0031
 *  http://lirc.sourceforge.net/remotes/toshiba/SE-R0031
 * Note that this has some similar codes
 *
 *  The IRremote library uses Pin 3 for the Anode (longer pin)
 *  We have made a ground pin on Pin 4 for the Cathode (shorter pin)
 * 
 *
 */

#include <IRremote.h>

int pinGND=4;  // Longer leg on the IR LED
int pinLED=13; // The heartbeat LED on the board

int secs;
int heartbeat=0;
int playtime= 1*60;      // set here ypur DVD title playtime in sec leave a little extra
//int  playtime= 10;      // testing

IRsend irsend;

void setup() {
  pinMode(pinGND,OUTPUT);
  pinMode(pinLED,OUTPUT);
  Serial.begin(115200);

  Serial.println("Toshiba DVD SD1091EKE Synchronizer $Rev$");
  Serial.println("For Steina");
  Serial.println("Code by Joe Foley <foley@ru.is>");
  Serial.println("$URL$");
  Serial.println("$Id$");
  Serial.print("Playtime: ");
  secs=playtime;
    Serial.print("sec:");
    Serial.print(secs);
    Serial.print(" / mm:ss ");
    Serial.print(secs/60);
    Serial.print(":");
    Serial.print(secs % 60);
    Serial.println("");

  // The DVD player starts playing automatically, so we should pause it
  send_pause();
  waitsec(3);
  secs=playtime;

}

/********************************************************************/
void loop() {
  Serial.println("Sync");
  send_previous();
  // on this model, previous immediately starts playing

  for(int t = 0; t < playtime; t++) {
    // This will not give us perfect 1 second timing
    //   but it is good enough for most video applications
    // The most critical is having everything start at the
    //   same time.
    Serial.print("sec:");
    Serial.print(playtime);
    Serial.print(" / mm:ss ");
    Serial.print(t/60);
    Serial.print(":");
    Serial.print(t % 60);
    Serial.println("");
    if (heartbeat == 1) {
      digitalWrite(pinLED, HIGH);
      heartbeat = 0;
    }
    else {
      digitalWrite(pinLED, LOW);
      heartbeat = 1;
    }
    delay(1000);
  }

  send_pause();
  waitsec(1);

}

/**************************************************************/
void waitsec(int sec) {
  Serial.print("Wait ");
  Serial.print(sec);
  Serial.println(" seconds");
  delay(sec*1000);
}


/********************************************************************/
  // NEC data format: first comes the pre-data bits, then the command code
void send_stop() { 
    Serial.println(" stop");
    irsend.sendNEC(0xA25D28D7,32); 
}

/********************************************************************/
void send_play() { 
  // Note that play and pause are a toggle for the same command
  Serial.println(" play");
  irsend.sendNEC(0xA25DA857, 32); 

}

/********************************************************************/
void send_pause() {
  // On this model, pause and play are the same button so it toggles
  // We use the "step" command which will always pause, no matter
  //   how many times we press it.
  Serial.println("  step/pause");
  irsend.sendNEC(0xA25D00FF,32); 
}	

/********************************************************************/
void send_previous() {  
  // First comes the pre-data bits, then the command code
  Serial.println(" previous");
  irsend.sendNEC(0xA25DC43B, 32); 
}